[ NotesNotif ;	! à mettre en DERNIER dans les routines!
	if (isVorpleSupported()) {
		VorpleNotification("Intéressant ! Cette information a été ajoutée à vos notes.");
	} else {
		style underline; print "^^[Intéressant ! Cette information a été ajoutée à vos notes.]"; style roman;
	}
	return true;
];



! mod 2 = objectif 1, mod 4 = objectif 2 | objectif 1, mod 8 = objectif 3 | objectif 2 | objectif 1
Global objectifs = 0;


!==========================================================
!  Objectif 1 : trouver la consommation du village


!====================
!   Infos

! Conso générateur : 100 L / semaine
! Conso bateau (Dong Feng 6.6cv) : 1L/heure/moteur ; un aller-retour par jour pour Revatua et Varii, c'est 27L/semaine
Constant conso_initiale = 127;
Global conso = conso_initiale;
! Au début du jeu, Revatua va au village tous les X jours
Global jours = "onze";

! Efficacité des générateurs (0.x)
Global efficacite_generateur1 = 20;
Global efficacite_generateur2 = 20;

! Pertes en ligne (en %)
Constant pertes_ligne = 13;

! Conso du village
Constant vrai_nbrwatts = 63;
! Résultats calculés
Global nbrwatts_efficacite = 0;
Global nbrwatts_puissance = 0;

! Conso des bateaux
Global conso_bateau_revatua = 14;
Global conso_bateau_varii = 13;

! Information "Revatua va chercher un baril de 200L tous les X jours" - 0 ou 1
Global connait_conso = 0;
! Connaissance de l'efficacité du générateur - 0, 1 si parle au maire ou revatua, 2 si on lit le mode d'emploi
Global connait_rendement = 0;
! Puissance des générateurs : 0 no idea, 1 on la connaît, 2 on sait qu'il y a des pertes en ligne, 3 on la connaît et on sait qu'il y a des pertes
Global generateur_puissance = 0;

! Consommation des bateaux : 1 celui de Revatua, 2 celui de Varii, 3 les deux
Global conso_bateaux = 0;

! La sous-quête du pêcheur amoureux
Global pecheur_amoureux = 0;


!=================
!  Affichage de la consommation / du score


[ Consommation ;
	if (connait_conso == 0) {
		print "Vous ne connaissez pas encore la consommation du village";
		if (deadflag) { print ", mais vous l'avez réduite @{2014} accomplissez les autres objectifs pour en savoir plus !"; } else { print "."; }
		"";
	}
	if (objectifs % 2 == 1) { print "Vous avez rempli le premier objectif"; if (nbrwatts_puissance == nbrwatts_efficacite) {print " @{2014} et vous avez même calculé la consommation de deux façons différentes !"; } else { print "."; } }
	if (conso == conso_initiale) { "Vous n'avez pas encore réduit la consommation de votre communauté."; }
	else {
		! Afficher la consommation actuelle, et le pourcentage
		print "Vous avez réduit la consommation de votre communauté de ";
		Pourcentage();
		print "%.^^";
		print "La consommation actuelle est d'environ ";
		print conso;
		print "L par semaine.";
		if (deadflag) { ""; }
	}
	style underline;
	print "^^[Pour voir votre rapport détaillé, tapez NOTES.]";
	style roman;
	"";
];


! Pour la statusbar et autres
[ Pourcentage ;
	! au début c'est 0
	if (conso == conso_initiale) { print "0"; return true; }
	! si on réduit mais on connaît pas la conso totale, c'est ?
	if (connait_conso == 0) { print "?"; return true;}
	! si on connaît tout ça c'est le pourcentage
	print (100*(conso_initiale-conso)/conso_initiale); return true;
];

[ congrats ;
!	if (conso < 9*(conso_initiale/10) + 5) { ! fudge pour éviter un bug
		print "Bien joué ! Vous avez atteint les objectifs que les chefs vous avaient fixés ! Grâce à vous le village dépense moins en énergies fossiles, et est moins vulnérable économiquement !"; "";
!	}
	if (conso < 2*(conso_initiale/3)) {	! -33%
		print "Super ! Vous avez réduit la consommation du village d'un tiers ! Grâce à vous le village économise de l'argent sur ses besoins en énergie et est moins vulnérable aux flambées du pétrole ; la communauté est plus forte !"; "";
	}
	if (conso < conso_initiale/2) {		!-50%
		print "Bravo ! Vous avez réduit la consommation du village de moitié ! Autant d'argent qui reste dans la communauté, qui est ainsi plus riche et plus résiliente, et fonctionne désormais en majorité grâce aux énergies renouvelables !"; "";
	}
	if (conso < conso_initiale/4) {		!-75%
		print "Excellent !! Vous avez réduit la consommation du village de plus de 75% ! C'est autant d'argent économisé et autant de dixoyde de carbone non émis ! Le village tire maintenant la majorité de son électricité de sources renouvelables et locales, et peut envisager un avenir stable, serein et florissant, sans se préoccuper des flambées du pétrole !"; "";
	}
	if (conso < conso_initiale/20) {	!-95% (
		print "Incroyable ! Grâve à vous le village n'a virtuellement plus besoin d'énergies fossiles ! Votre travail sans relâche permet à votre communauté d'être un modèle de développement durable, en exploitant ses ressources locales d'énergie sans contribuer au réchauffement climatique !"; "";
	}
	"";

];

[ ScoreSub ;
	Consommation();
	if (deadflag) {
		congrats();
		print "^^... Mais le combat continue, à travers le monde ! Les communautés du Pacifique, en particulier, sont très vulnérables à la montée du niveau de la mer engendrée par le réchauffement climatique.";
		style underline;
		print "^^Si ce jeu vous a plu, je vous suggère de faire un don à une association de protection de l'environnement de votre choix ! (Et si vous ne savez pas à qui donner, quelques suggestions : Atmosfair (installation d'énergie renouvelable dans les pays en voie de développement), Surfrider Foundation (protection des océans), Adaptation Fund (le fonds de l'ONU pour financer l'adaptation au réchauffement climatique).) Merci beaucoup !";
		style roman;
		"";
	}
];


!====================
! Petits calculs du joueur

Constant update_Conso_Diesel = 0;
Constant update_Conso_Bateau = 4;
Constant update_Rendement = 1;
Constant update_Pertes = 2;
Constant update_Puissance = 3;


[ PetitCalculLTokWh ;
	print " Voyons voir, ", ConsoGene(), " litres par semaine, 0.2 L par "; Tooltip("kWh", "1000 joules (unités d'énergie) produites chaque seconde pendant une heure."); print "... ça donne ";
	switch(ConsoGene()) {
		127: print "91";
		114: print "81.5";
		113: print "80.5";
		100: print "72.5";
	}
	print " kWh générés, et en comptant ", pertes_ligne, "% de pertes en ligne vous trouvez le chiffre de ";
	switch(ConsoGene()) {	! 13%
		127: print "79"; nbrwatts_efficacite = 79;
		114: print "71"; nbrwatts_efficacite = 71;
		113: print "70"; nbrwatts_efficacite = 70;
		100: print "63"; nbrwatts_efficacite = 63;
	}
	print " kWh consommés par le village chaque jour.";
];


[ UpdatePremierObjectif i;

	! Première méthode : nombre de litres x efficacité x (1-pertes) = kwh (et donc puissance, mais bon)


	! On vient de trouver l'information "127L par semaine"
	if (i == update_Conso_Diesel) {
		! on peut l'utiliser que si on a l'information sur l'efficacité
		if (connait_rendement == 2) {
			print "^^Maintenant que vous connaissez la consommation en diesel du village, vous pouvez calculer la consommation en électricité du village !";
			! à ce stade-là on connaît forcément les pertes en ligne
			PetitCalculLTokWh();
		}
	}
	
	! On vient de trouver la consommation d'un bateau
	if (i == update_Conso_Bateau) {
		if (connait_conso == 0) { print "^^Vous gardez cette information en tête ; elle vous servira quand vous aurez trouvé la consommation totale de diesel du village."; }
		else {	! on connaît la conso
			if (connait_rendement == 2) {	! on a déjà fait un calcul et il était faux
							! on connaît forcément déjà les pertes en ligne
				print "^^Ah, zut @{2014} vous n'aviez pas pensé à ça lorsque vous vous aviez calculé la consommation en électricité du village. Vous refaites le calcul rapidement : on a donc ", ConsoGene(), " litres par semaine, 0.2 L par "; Tooltip("kWh", "1000 joules (unités d'énergie) produites chaque seconde pendant une heure."); print "... ça donne ";
			switch(ConsoGene()) {
				114: print "81.5";
				113: print "80.5";
				100: print "72.5";
			}
			print " kWh générés, et en comptant ", pertes_ligne, "% de pertes en ligne vous trouvez le chiffre de ";
			switch(ConsoGene()) {	! 13%
				114: print "71"; nbrwatts_efficacite = 71;
				113: print "70"; nbrwatts_efficacite = 70;
				100: print "63"; nbrwatts_efficacite = 63;
			}
			print " kWh consommés par le village chaque jour.";
			} else {	print "^^Vous gardez cette information en tête ; elle vous sera utile lorsque que vous aurez trouvé comment relier la consommation en diesel et celle en électricité.";	}
		}
	}
	
	! On vient de trouver le chiffre de l'efficacité du générateur
	if (i == update_Rendement) {
		if (connait_conso == 0) { print "^^Vous gardez cette information en tête ; elle vous servira quand vous aurez trouvé la consommation totale de diesel du village."; }
		else {	! on connaît nécessairement les pertes
			print "^^Vous avez maintenant un moyen de calculer la consommation électrique à partir de la consommation en diesel !"; 
			PetitCalculLTokWh();
		}
	}
	
	
	
	! Deuxième méthode : puissance x heures x (1-pertes) = kwh (et donc conso diesel si on connaît l'efficacité)
	
	! On vient de lire le mode d'emploi
	if (i == update_Pertes) {
		! à ce stade-là on n'a pas l'efficacité alors on ne peut rien dire sur l'autre calcul
		if (generateur_puissance % 2 == 1) { ! on connaît la puissance des générateurs (donc on a déjà fait un calcul faux)
			print "^^Ah zut, ça change votre calcul, alors @{2014} vous n'aviez pas pensé aux pertes en ligne quand vous avoez calculé la consommation du village à partir de la puissance des générateurs... Il suffit juste de diminuer la valeur de ", pertes_ligne, "%, ce qui donne 63 kWh consommés par le village par jour."; nbrwatts_puissance = 63;
		} else { print "^^Vous gardez cette information en tête ; elle est importante pour quand vous calculerez la consommation électrique du village."; }
	}
	
	! On vient de lire le cadran
	if (i == update_Puissance) {
		print "^^Intéressant @{2014} alors, les générateurs produisent en tout 14.5 kW, pendant 5 heures par jour...";
		if (generateur_puissance < 2) { ! on sait pas qu'il y a des pertes en ligne alors le calcul est faux
			print " Ça donne 72.5 kWh par jour consommés par le village. Vous notez cette information.";
			nbrwatts_puissance = 73;
		} else {	! on sait qu'il y a des pertes en ligne
			print " moins ", pertes_ligne, "%, bien sûr, et ça donne 63 kWh par jour. Vous notez cette information.";
			nbrwatts_puissance = 63;
		}
	}
	
	
	! Enfin, test si les deux valeurs concordent
	if (nbrwatts_puissance ~= 0 && nbrwatts_efficacite ~= 0) {
		if (nbrwatts_puissance == nbrwatts_efficacite) { print "^^Hé, le chiffre que vous avez calculé à partir de la puissance du générateur est le même que celui calculé à partir de la consommation de diesel et l'efficacité du générateur ! C'est que ça doit être juste alors !"; }
		else { print "^^Mmh, le chiffre que vous avez calculé à partir de la puissance du générateur est différent de celui calculé à partir de la consommation de diesel et l'efficacité du générateur... Vous avez dû oublier de prendre en compte quelque chose dans vos calculs."; }
	}
	
	print "^"; ! pour faire semblant que tout est bon, mais j'ai l'impression qu'il y a un bug (on reste collé dans la notification?)
	"";
];



!==================================================
!   Objectif n°2

! 80w + 80w + 10w + 10w + lampes (7 lampes, 2.5 h à 70w)  = 1.4kwh
Global conso_unemaison_salon = 14;
! une plaque chauffante c'est 1000-1500W ; on peut dire "un repas par jour sur 2 plaques pendant 1 heure" (modulo les fois où ils mangent au restau, où ils réchauffent des trucs sur un barbecue, etc) : 2.4 kWh par foyer
Global conso_unemaison_cuisine = 24;
!  x 11 maisons (elles consomment toutes à peu près pareil)
Global nombre_maisons = 11;

! école : 10 ampoules (grande salle) pendant 1h : 7kwh
Global conso_ecole = 7;

! puits : sur amazon, un moteur à puits profond consomme 900W pour 3300L/h ; 36 personnes, une douche et la lessive et la vaisselle tout ça, c'est sûrement 100L/jour, donc on dit qu'il faut 1h pour remplir la cuve : 1kwh
!http://www.amazon.fr/dp/B001B44QUO/ref=asc_df_B001B44QUO31037087?smid=A11EQC7DR73POB&tag=legugrounetw_hi_mp-21&linkCode=df0&creative=22802&creativeASIN=B001B44QUO&ascsubtag=[B001B44QUO]-21
Global conso_puits_village = 10;

!  ah mais il faut de l'eau pour le taro : dans la vraie vie l'agriculture c'est bien plus que les personal needs (et on n'a même pas de toilettes ou de dishwasher et tout hein). Alors 1.9 kWh parce que ça nous arrange (ah mais je suis bête il a son puits personnel)
Global conso_puits_taro = 20;

! sagefemme : un lavage à l'eau chaude dans une lavelinge récent c'est 0.6kwh ; on va dire qu'elle en fait 1 par jour (elle stérilise les trucs qu'elle a + peut-être laver les couches des mères)
!    on peut dire que c'est un vieux pas efficace : selon les standards canadiens actuels (2015) les plus consommateurs c'est 400kWh par an ; mais si elle a un vieux lave-linge, on peut dire que c'est 2.4 kWh par jour (en 15 ans la conso des lave-linges a diminué de moitié)
Global conso_sagefemme = 24;

! restau (machine à faire de la glace ? ventilateurs? ché pas) : 1kwh
Global conso_restau_salle = 9;
! http://www.amazon.com/Frigidaire-FFEF3048LS-Electric-Range-Stainless/dp/B003HIO8CS/ref=sr_1_2?ie=UTF8&qid=1451773179&sr=8-2&keywords=stove
! = 2 éléments à 1200W + 1 2600W + 1 1800W, et "bake" c'est 2600W et "broil" c'est 3000W (on fudge et on dit 2400)
!   2h de four, 2h de mijotage + 1h chacun les autres : 14.2kwh par jour
Global conso_restau_cuisine = 142;


! Les nombres ci-dessus sont multipliés par 10 pour qu'ils soient entiers
[ SurDix i	j k;
	j = i % 10;
	k = (i-j)/10;
	print k, ",", j;
	return true;
];


!=============
! Flags

! 0 = aucune idée, 1 on connaît la conso des appareils, 2 on connaît la conso de la cuisine, 3 on connaît les deux
Global connait_conso_unemaison = 0;
! 1 = on sait qu'elles consomment toutes pareil
Global sait_maisons_pareilles = 0;

! 1 si tu connais la puissance, 2 si tu sais combien de temps il reste allumé, 3 pour les deux
Global connait_conso_puits_vill = 0;
Global connait_conso_puits_taro = 0;

! 1 = on connait la conso de la sage-femme
Global connait_conso_sagefemme = 0;

! 1 = on connait la conso de l'école
Global connait_conso_ecole = 0;

! 1 = on connait la conso du restau, 2 = on connait la conso de la cuisine du restau, 3 = les deux
Global connait_conso_restau = 0;


!==================================================
!  Objectif 3 : le gros du jeu (enfin, plus tard)


! 1 : on a parlé de l'huile de coco à Maihere : il dit que c'est pas rentable si on lui donne pas un bon prix
! 2 : on a parlé à un chef, qui dit "est-ce que ça va marcher, demande à Tiniarii"
! 3 : on a parlé à Tiniarii, qui dit "filtre à 5 microns et cuve truc : dis le au chef"
! 4 : on a parlé à un chef, qui dit "va demander l'avis économique de revatua"
! 5 : on a parlé à Revatua, qui dit "un litre de coco se vend à 1.5 mais s'achète à 1$, on paie 1.75$ pour le diesel, entre les deux... va voir ahutoru" - et les filtres à 5 microns ok ça ira
! 6 : on a parlé à un chef, qui dit "on a de l'argent des rémitances, on économise un peu, allez on le fait. propose-lui un prix de 1.4$, c'est mieux, l'argent reste dans la communauté, et on économise un peu, et il pourra vendre le coprah"
! 7 : on a parlé à Maihere, qui dit "ok ! mais ma production c'est que <tant>. et faudra sans doute adapter le générateur, va voir le chef pour lui dire que c'est oui"
! 8 : on a parlé à un chef, qui dit " bravo, gagné !"
Global coconut_quest = 0;


! Idées pour réduire la consommation
!
!   Remplacer le diesel par l'huile de coprah dans les bateaux
!   Remplacer le diesel par l'huile de coprah dans les générateurs (20%)
! 
! Pas implantés (dans le futur)
!
!   "Chauffe-eau solaire" (bidon noir) pour la machine à laver de la sage-femme
!   "Chauffe-eau solaire" (bidon noir) pour la restauratrice
!   Four solaire pour la restauratrice
!   Puits taro: une petite éolienne qui tire de l'eau quand y'a du vent (toute la journée donc)
!   Puits village: une petite éolienne ou utiliser la micro-hydro (cascade)
!   Plantation de torea : j'avais pensé au coup du "arroser le soir pas le matin", au moins pour les patates douces ; parce que le taro ça s'arrose pas vraiment, et le pandanus y'a pas vraiment besoin (et c'est presque pas cohérent qu'il soit là)
!   Acheter des LED pour tout le monde avec l'argent économisé
!   Acheter un meilleur lave-linge pour la sage-femme
!   OMG! Le pêcheur, célibataire, est amoureux de la sage-femme (on l'apprend par son ado, et par son attitude). Si ils tombent amoureux et qu'ils emménagent ensemble, la maison de la sage-femme est vide et ne consomme plus d'électricité : dawww
!   Un volant d'inertie pour stocker de l'énergie
!   Faire un moulin à coprah à partir de la cascade pour augmenter la production d'huile
!
! Est-ce faisable d'utiliser les vagues dans la crique comme source d'énergie (et comment la transmettre surtout)
! Récupération de l'eau de pluie ? (pour arroser le taro, mais il va pas faire le tour du village avec sa brouette...)
! Voiles sur les bateaux ?


!==================================================
!  Rapport détaillé

! estimation de la consommation du générateur par le joueur
[ ConsoGene i;
	i = conso;
	if (connait_conso == 0) { return "?"; }
	if (conso_bateaux ~= 0) {
		if (conso_bateaux >= 2) { i = i - conso_bateau_varii; }
		if (conso_bateaux % 2 == 1) { i = i-conso_bateau_revatua; }
	}
	return i;
];

[ CalculObjectifDeux 	i;
	i=0;
	if (sait_maisons_pareilles == 1 && connait_conso_unemaison == 3) { i = i + (conso_unemaison_salon+conso_unemaison_cuisine)*nombre_maisons; 	}
	if (connait_conso_ecole ~= 0) { i = i + conso_ecole; }
	if (connait_conso_sagefemme ~= 0) { i = i + conso_sagefemme; }
	
	if (connait_conso_puits_vill == 3) { i = i + conso_puits_village; }
	
	if (connait_conso_puits_taro == 3) { i = i + conso_puits_taro; }
	
	if (connait_conso_restau % 2 == 1) { i = i + conso_restau_salle; }
	if (connait_conso_restau >= 2) { i = i + conso_restau_cuisine; }
	
	return i;
];

[ RapportSub ;
	print "Vous consultez vos notes.^^===================^^";
	
	style bold; print "Premier objectif :"; style roman; print " calculer la consommation électrique du village.";
	if (objectifs % 2 == 1) { style bold; print " (Fait !)"; style roman; } ! TODO: couleur ?
	print "^";
	if (connait_conso == 1) {
		print "^@{2014} Consommation initiale en diesel du village : ", conso_initiale, " L par semaine.";
	} else { print "^ @{2014} Consommation de diesel du village : ? L par semaine."; }
	
	if (conso_bateaux ~= 0) {
		print "^   @{2014} Consommation du bateau de Revatua : "; if (conso_bateaux % 2 == 1) { print "14"; } else { print "?"; } print " L par semaine";
		print "^   @{2014} Consommation du bateau de Varii : "; if (conso_bateaux < 2) { print "?"; } else { print "13"; } print " L par semaine";
	}
	if (connait_conso == 1) {
		print "^   @{2014} Diesel consommé par le générateur : ", ConsoGene(), " L par semaine.";
	}
	
	if (generateur_puissance ~= 0) {
		if (generateur_puissance % 2 == 1) {print "^ @{2014} Puissance à laquelle tournent les générateurs : 7.25 kWh"; }
		if (generateur_puissance >= 2) { print "^     (ne pas oublier de compter les ", pertes_ligne, "% de perte dûes à la distribution de l'électricité !)"; }
	}
	
	if (connait_rendement == 2) {
		print "^ @{2014} Rendement actuel :  générateur n@{BA}1 = 0,", efficacite_generateur1, " L par "; Tooltip("kWh", "1 !kilowatt-heure = 1000 unités d'énergie délivrées chaque seconde pendant 1 heure");
			print ", générateur n@{BA}2 = 0,", efficacite_generateur2, "L par kWh.^     (l'efficacité diminue un peu à mesure que la puissance diminue)";
	}
	
	print "^ @{2014} Heures de consommation d'électricité : 2 heures le matin, 3 heures le soir.";
	
	print "^^Estimation de la consommation d'électricité du village chaque jour :";
		if (nbrwatts_puissance ~=0) {
			if (nbrwatts_efficacite ~=0) {
				if (nbrwatts_efficacite == nbrwatts_puissance) { print "^  ", nbrwatts_puissance, " kWh (vérifié de deux façons)."; }
				else { print "^  ", nbrwatts_puissance, " kWh ? ", nbrwatts_efficacite, " kWh ? (incohérence @{2014} pourquoi ?)"; }
			}
			else { print "^  ", nbrwatts_puissance, " kWh."; }
		} else {
			if (nbrwatts_efficacite == 0) { print "^   ? kWh"; }
			else { print "^   ", nbrwatts_efficacite, " kWh."; }
		}
		
		
		
		
		
	print "^^^";
	
	style bold; print "Deuxième objectif :"; style roman; print " détailler qui consomme quoi dans le village.";
	if (objectifs % 4 >= 2) { style bold; print " (Fait !)"; style roman; } ! TODO: couleur ?
	
	if (connait_conso_unemaison ~= 0 || sait_maisons_pareilles == 1) {
		print "^ @{2014} Maison des parents :";
		if (connait_conso_unemaison ~= 0) {
			if (connait_conso_unemaison % 2 == 1) { print "^   @{2014} Salon et éclairage : "; SurDix(conso_unemaison_salon); print " kWh"; }
			if (connait_conso_unemaison >= 2) { print "^   @{2014} Cuisine : "; SurDix(conso_unemaison_cuisine); print " kWh"; }
		}
		if (sait_maisons_pareilles == 1) { print "^    (toutes les maisons consomment pareil : multiplier par ", nombre_maisons, ")"; }
		if (sait_maisons_pareilles == 1 && connait_conso_unemaison == 3) {
			print "^Total pour les maisons : "; SurDix( (conso_unemaison_salon+conso_unemaison_cuisine)*nombre_maisons); print " kWh";
		}
	}
	if (connait_conso_ecole ~= 0) { print "^ @{2014} École : "; SurDix(conso_ecole); print " kWh"; }
	if (connait_conso_sagefemme ~= 0) { print "^ @{2014} Lave-linge de Vavea : "; SurDix(conso_sagefemme); print " kWh"; }
	
	if (connait_conso_puits_vill ~= 0) {
		print "^ @{2014} Puits du village : ";
		if (connait_conso_puits_vill == 3) { SurDix(conso_puits_village); } else { print "?"; }
		print " kWh ("; if (connait_conso_puits_vill % 2 == 1) { print "1000"; } else { print "?";}
		print " W, allumé "; if (connait_conso_puits_vill >= 2) { SurDix(conso_puits_village); } else { print "?"; }
		print " heures par jour).";
	}
	if (connait_conso_puits_taro ~= 0) {
		print "^ @{2014} Puits de la plantation de Torea : ";
		if (connait_conso_puits_taro == 3) { SurDix(conso_puits_taro); } else { print "?"; }
		print " kWh ("; if (connait_conso_puits_taro % 2 == 1) { print "1000"; } else { print "?";}
		print " W, allumé "; if (connait_conso_puits_taro >= 2) { SurDix(conso_puits_taro); } else { print "?"; }
		print " heures par jour).";
	}
	
	if (connait_conso_restau ~= 0) { print "^ @{2014} Restaurant :";
		if (connait_conso_restau % 2 == 1) { print "^   @{2014} Salle : "; SurDix(conso_restau_salle); print " kWh"; }
		if (connait_conso_restau >= 2) { print "^   @{2014} Cuisine : "; SurDix(conso_restau_cuisine); print " kWh"; }
	}
	
	print "^Total : "; SurDix(CalculObjectifDeux()); print " kWh.";
	
	
	print "^^^";

	style bold; print "Troisième objectif :"; style roman; print " réduire la consommation totale du village.";
	print "^^@{2014} Consommation actuelle en diesel du village : ", conso, " L par semaine ("; Pourcentage(); print "% de réduction).";
	
	print "^^===================^^";
	
	style bold; print ""; style roman;
	"";
];

[ MontrerRapportSub ;
	L__M(##Show, 2, noun); rtrue;
];

Verb 'notes' 'rapport' 'enquete'
*		->Rapport;

Extend only 'voir' first
* 'notes'/'rapport'/'enquete'	->Rapport;
Extend only 'consulter' first
* 'notes'/'rapport'/'enquete'	->Rapport;
Extend 'afficher' first
* 'notes'/'rapport'/'enquete'	->Rapport;
Extend 'examiner'
* 'notes'/'rapport'/'enquete'	->Rapport;

Extend only 'montrer' first
* 'notes'/'rapport'/'enquete'	->Rapport
* 'notes'/'rapport'/'enquete' 'a'/'au' creature		->MontrerRapport;